枚举和枚举类型

 

枚举对象是枚举类型的多寡对象。枚举对象只可以分包类型为枚举类型的枚举值。ABAP从版本7.51始发援助它们。

那是风度翩翩种布衣蔬食的情势。在ABAP 7.51事先,大家平日用如下方式实现相同的功能:

CLASS cx_wrong_size DEFINITION INHERITING FROM cx_static_check.
 ENDCLASS.

 CLASS shirt DEFINITION.
   PUBLIC SECTION.
     TYPES tsize TYPE i.
     CONSTANTS:
       size_s  TYPE tsize VALUE 0,
       size_m  TYPE tsize VALUE 1,
       size_l  TYPE tsize VALUE 2,
       size_xl TYPE tsize VALUE 3.
     METHODS
       constructor IMPORTING size TYPE tsize
                   RAISING   cx_wrong_size.
     ...
   PRIVATE SECTION.
     DATA
       size TYPE tsize.
 ENDCLASS.

 CLASS shirt IMPLEMENTATION.
   METHOD constructor.
     IF size <> size_s AND
        size <> size_m AND
        size <> size_l AND
        size <> size_xl.
       RAISE EXCEPTION TYPE cx_wrong_size.
     ENDIF.
     me->size = COND #(
       WHEN size <> size_s AND
                    size <> size_m AND
                    size <> size_l AND
                    size <> size_xl THEN THROW cx_wrong_size( )
       ELSE size ).
   ENDMETHOD.
 ENDCLASS.

此地,size属性只好够是shirt类中定义的常量中的值。其余值会以致至极。客商创立shirt类时,须求这么做:

TRY.
    DATA(shirt) = NEW shirt( shirt=>size_xl ).
  CATCH cx_wrong_size.
    ...
ENDTRY.

看到成本了吗?为啥不让运转时情况来为您做值检查吧?有生机勃勃种叫做枚举和枚举类型的定义(能够在此种状态下选取卡塔尔。

在7.51以至更加高的版本里,ABAP也会支撑枚举概念。要是选择枚举类型来重写上边包车型客车例子的话:

CLASS shirt DEFINITION.
  PUBLIC SECTION.
    TYPES:
      BEGIN OF ENUM tsize,
        size_s,
        size_m,
        size_l,
        size_xl,
      END OF ENUM tsize.
    METHODS
      constructor IMPORTING size TYPE tsize.
    ...
  PRIVATE SECTION.
    DATA
      size TYPE tsize.
ENDCLASS.

CLASS shirt IMPLEMENTATION.
  METHOD constructor.
    me->size = size.
  ENDMETHOD.
ENDCLASS.

TYPES语句的叁个新变式:BEGIN OF ENUMEND OF
ENUM
,它能够围起二个常量的集。常量的行业内部基本项目是i並且枚举值从0开头计数。

像上文那样采纳的话:

DATA(shirt) = NEW shirt( shirt=>size_xl ).

唯独,使用了枚举对象后,你不再须求管理特别了。假诺你传递三个违法值的话,会得到语法错误!

DATA(shirt) = NEW shirt( 333 ).

图片 1

 

枚举是项目和常量的混合体。通过BEGIN OF ENUM enum – END OF ENUM
enum

你注明了八个足以在TYPE附加项后声称的宗旨项目enum。在它们中间,你能够声飞鹤(Beingmate卡塔尔个常量集,它们叫做枚举常量。这样就定义了装有enum品种的枚举对象所允许的枚举值。在此边,TYPES其实就和CONSTANTS话语同样。

ABAP运营时景况会检查只有被允许的枚举值能够被赋给枚举对象。

TYPES:
  BEGIN OF ENUM tsize,
    size_s,
    size_m,
    size_l,
    size_xl,
  END OF ENUM tsize.

DATA size TYPE tsize.
size = size_xl. "允许

DATA dobj LIKE size.
dobj = size. "允许

dobj = 333. "语法或运行时错误

枚举对象只可以赋值给全数意气风发致枚举类型的枚举对象。相符,枚举对象间的可比也一定要在相似类其余枚举对象间发生。当然,枚举常量本人也饱含在内。

普通,你或多或少也不关怀枚举对象的剧情。枚举对象的语义由枚举常量来定义。但是,你也足以将枚举类型定义为i类型之外的别样基本项目,并且有着别样枚举值(此中一个亟须是开头值卡塔尔国:

TYPES:
  basetype TYPE c LENGTH 2,
  BEGIN OF ENUM tsize BASE TYPE basetype,
    size_i  VALUE IS INITIAL,
    size_s  VALUE `S`,
    size_m  VALUE `M`,
    size_l  VALUE `L`,
    size_xl VALUE `XL`,
  END OF ENUM tsize.

DATA size TYPE tsize.
size = size_xl. "允许

DATA dobj LIKE size.
dobj = size."允许

那令你能够轻易地把现成“枚举值”转变为新办法的枚举值。运气好的话,能够无需调节它们的运用。

要是您在叁个上下文中有胜过叁个枚举类型,你能够将次第枚举值组织到组织里:

TYPES:
  BEGIN OF ENUM tsize STRUCTURE size,
    s,
    m,
    l,
    xl,
  END OF ENUM tsize STRUCTURE size.

DATA dobj TYPE tsize.
dobj = size-xl. "允许

如上代码定义了三个枚举结构size。结构的机件是枚举类型的枚举常量。

 

枚举对象的宽广用场是比较它和枚举常量以决定程序需求切换来哪一个功能分支:

TYPES:
  BEGIN OF ENUM tsize STRUCTURE size,
    s,
    m,
    l,
    xl,
  END OF ENUM tsize STRUCTURE size.

DATA dobj TYPE tsize.

...

CASE dobj.
  WHEN size-s.
    ...
  WHEN size-m.
    ...
  WHEN size-l.
    ...
  WHEN size-xl.
    ...
ENDCASE.

 除此而外,还只怕有部分能够使用的情景:

你能够将枚举对象赋给叁个c品种可能string品类的公文。结果就是概念了枚举值的枚举常量的名字。

TYPES:
  BEGIN OF ENUM tsize,
    size_s,
    size_m,
    size_l,
    size_xl,
  END OF ENUM tsize.

DATA text TYPE string.
text = size_xl.
cl_demo_output=>display( text ). "结果是SIZE_XL

也得以创作:

DATA(text) = CONV string( size_xl ).

能够运用CONV操作符钦点项目来访谈当前值:

TYPES:
  BEGIN OF ENUM tsize,
    size_s,
    size_m,
    size_l,
    size_xl,
  END OF ENUM tsize.

DATA(value) = CONV i( size_xl ) .
cl_demo_output=>display( value ). "输出结果是3

另后生可畏种方法是,能够应用CONV将七个有效的枚举值转换为枚举对象(常规的赋值语句是力不能支成功的卡塔 尔(阿拉伯语:قطر‎:

TYPES:
  BEGIN OF ENUM tsize,
    size_s,
    size_m,
    size_l,
    size_xl,
  END OF ENUM tsize.

DATA(num) = 3.

TRY.
    DATA(dobj) = CONV tsize( num ) .
    cl_demo_output=>display( dobj ). "Output is SIZE_XL
  CATCH cx_sy_conversion_no_enum_value.
    ...
ENDTRY.

RTTI中也多了三个相应的类CL_ABAP_ENUMDESCR

TYPES:
  BEGIN OF ENUM tsize,
    size_s,
    size_m,
    size_l,
    size_xl,
  END OF ENUM tsize.

DATA(size) = VALUE tsize( ).

DATA(enum_descr) = CAST cl_abap_enumdescr(
  cl_abap_typedescr=>describe_by_data( size ) ).

cl_demo_output=>new(
  )->write_data( enum_descr->kind            "E, for elementary
  )->write_data( enum_descr->type_kind       "k, new for enumerated type
  )->write_data( enum_descr->base_type_kind  "I, the base type
  )->write_data( enum_descr->members         "Table of constants and values
  )->display( ).

基本上正是那一个剧情了。

躺下让ABAP运转时来为您办事啊。要留意枚举类型只可以在少数符合的运算地点中冒出,而且一定要分包预先规定的值。违法的枚举值永世不会在枚举对象中现身。

 

PS:原来的文章的评价中有人涉嫌,枚举值和数据字典中的domain的固定值很像,为何双方未有并轨关系?

笔者的答问是:那几个特点实际三春经在规划中了,很有期望现身。具体情状要视能源和事先级而定。

 

正文链接:http://www.cnblogs.com/hhelibeb/p/7976078.html

菲律宾语原稿:ABAP News for Release 7.51 –
Enumerations

 

相关文章